Show Posts
1
Software / Directx 9a
« on: June 07, 2003, 07:16:08 PM »
Hmm... well Im not sure I completely understand what you are asking but I thought I would add how I obtained the DX 9.0a files for Windows 2000.
If you install Dx9.0a over any DX version greater than 8 or so it does NOT download the [font=\"Courier\"]dinput_all_81.cab[/font] because those files are not updated (these are the 186 weird files in the [font=\"Courier\"]system32\directx\dinput[/font] folder).
One catch is that (at least for win2k) some of the files need to have their extension renamed, so I wrote a batch file to do the extraction from the [font=\"Courier\"]websetup[/font] directory and to rename the 3 files FOR WIN2K. The renaming stuff was pulled from the inf files.
[font=\"Courier\"]DXWebExtract.bat[/font]:
- Open windows explorer and navigate to the [font=\"Courier\"]system32\directx[/font] folder.
- Run the DirectX download program [font=\"Courier\"]dxwebsetup.exe[/font]. This downloads the compressed files to the [font=\"Courier\"]system32\directx\websetup[/font] folder.
- As soon as the download portion completes, copy the [font=\"Courier\"]websetup[/font] folder to the desktop. I did this by dragging'n dropping the folder from the explorer window onto the desktop while holding the Control key to copy it. Actually, I think you can even wait until the installation completes and the user is prompted to reboot because I believe the [font=\"Courier\"]websetup[/font] folder is not deleted until after the user clicks the button.
Code: [Select]
audio_nt.cab
audio_nt_eng.cab
bda_w2k.cab
dinput_all_81.cab
dinput_w2k_81.cab
dinput_w2k_81_eng.cab
dplay_nt.cab
dplay_nt_eng.cab
dsetup.dll
dsetup32.dll
dshow_nt.cab
dshow_nt_81.cab
dshow_nt_eng.cab
dshow_w2k_eng.cab
dxdiag_nt_eng.cab
filelist.dat
graphics_nt.cab
graphics_nt_eng.cab
graphics_w2k.cab
graphics_w2k_81.cab
ks_nt.cab
ks_nt_eng.cab
setup_all.cab
setup_w2k.cab
setup_w2k_eng.cab
vb_nt.cabIf you install Dx9.0a over any DX version greater than 8 or so it does NOT download the [font=\"Courier\"]dinput_all_81.cab[/font] because those files are not updated (these are the 186 weird files in the [font=\"Courier\"]system32\directx\dinput[/font] folder).
One catch is that (at least for win2k) some of the files need to have their extension renamed, so I wrote a batch file to do the extraction from the [font=\"Courier\"]websetup[/font] directory and to rename the 3 files FOR WIN2K. The renaming stuff was pulled from the inf files.
[font=\"Courier\"]DXWebExtract.bat[/font]:
Code: [Select]
@ECHO OFF
IF NOT EXIST "%~1" (
ECHO.Extracts DX cabinet files to DXNT and DXBDA folder for redistribution.
ECHO.
ECHO.usage: %~n0 "path to websetup folder"
ECHO.
ECHO.Uses cabarc.exe for extraction which needs to be in current path.
GOTO :EOF
)
SETLOCAL
SET fldr=%~f1
SET shrtfldr=%~fs1
SET d3d8thk=dll
SET joy=cpl
SET quartz=dll
FOR %%X IN (DXNT BDANT) DO IF NOT EXIST "%fldr%\%%X" MKDIR "%fldr%\%%X"
FOR %%X IN (*.cab) DO CALL :Extract "%%~fX"
:Rename
ECHO.
FOR /F "delims=" %%X IN ('DIR /B /S "%fldr%\*.w2k"') DO FOR /F "delims=" %%Y IN ('DIR /B /S "%%~dpnX.*"^| FINDSTR /V /C:.w2k') DO (
DEL /F "%%~fY"
REN "%%~fX" "%%~nxY"
)
:Name
FOR /F "delims=" %%X IN ('DIR /B /S "%fldr%\*.w2k"') DO CALL :MakeName "%%~fX"
GOTO :Done
:Extract
SET name=%~n1
IF "%name%"=="%name:bda=%" (SET dest=DXNT) ELSE (SET dest=BDANT)
cabarc.exe -o X %1 *.* %shrtfldr%\%dest%\
GOTO :EOF
:MakeName
ECHO.
IF DEFINED %~n1 (CALL SET filext=%%%~n1%%) ELSE SET /P filext=Enter the new extension for %~nx1:
ECHO Rename "%~nx1" to "%~n1.%filext%" ?
PAUSE
REN %1 "%~n1.%filext%"
GOTO :EOF
:Done
ENDLOCAL
\' />